REM TEST AREA
      INSTALL @lib$+"WINLIB5A"
      ON CLOSE PROC_closewindow(H%) : QUIT
      DIM hdr$(5), wid%(5), jst%(5)
      FOR I% = 0 TO 5
        hdr$(I%) = "Header " + STR$(I%)
        wid%(I%) = 120
        jst%(I%) = I% MOD 3
      NEXT
      H% = FN_lv_setup(@hwnd%, 0, 40, 800, 300, hdr$(), wid%(), jst%(), -1, &2000001)
      END
      REM /TEST AREA

      REM Create a standard List View. Returns the handle of the List View
      REM Perameters: h%         = parent window handle%,
      REM             x%, y%     = coordinates of the top left corner;
      REM             cx%, cy%   = width & height of the LV;
      REM             header$()  = header text array;
      REM             width%()   = column width array;
      REM             justify%() = column justification array;
      REM             lastcol%   = last column set (zero-based)
      REM             style%     = style of the LV
      REM LOCAL vars: LVCOLUMN{} = listview column structure
      REM             D%         = LV handle
      REM             C%         = column count
      REM             H$         = header string
      DEF FN_lv_setup(H%, X%, Y%, W%, V%, H$(), W%(), J%(), L%, S%)
      LOCAL LVCOLUMN{}, D%, C%, H$
      LVCF_FMT         = &1
      LVCF_WIDTH       = &2
      LVCF_TEXT        = &4
      LVCF_SUBITEM     = &8
      LVM_INSERTCOLUMN = &101B
      DIM LVCOLUMN{ mask%, fmt%, cx%, pszText%, cchTextMax%, iSubItem% }
      LVCOLUMN.mask%   = LVCF_FMT OR LVCF_SUBITEM OR LVCF_TEXT OR LVCF_WIDTH
      IF L% > DIM(H$(), 1) OR L% < 0 THEN L% = DIM(H$(), 1)
      SYS "InitCommonControls"
      D% = FN_createwindow(H%, "SysListView32", "", X%, Y%, W%, V%, 0, S%, 0)
      FOR C% = 0 TO L%
        H$                   = H$(C%) + CHR$(0)
        LVCOLUMN.fmt%        = J%(C%) MOD 3
        LVCOLUMN.cx%         = W%(C%)
        LVCOLUMN.pszText%    = !^H$
        LVCOLUMN.cchTextMax% = LEN(H$)
        LVCOLUMN.iSubItem%   = C%
        SYS "SendMessage", D%, LVM_INSERTCOLUMN, C%, LVCOLUMN{}
      NEXT
      = D%